<?xml version="1.0" encoding="utf-16" standalone="yes"?>
<!--Created: 17.07.2015 14:28:15-->
<!--ACTOptimumVersion: 6.0.5581.26549-->
<AutoDataItems ACTOptimumVersion="6.0.5581.26549" Created="17.07.2015 14:28:15">
    <AutoDataControl Created="17.07.2015 14:28:15" ClassName="Melville_Schellmann.ACTOptimum3.Control.AutoData3.AutoData3" PrefClassVersion="1.0" ACTOptimumVersion="6.0.5581.26549">
        <Source>' #ScriptName: SetKIParameter
    ' #Description: DEUTSCH:
    '               Fragt Parameter für eine KundenInfo Abfrage ab und speichert diese in der Registry. Danach wird ein BrowserTab aufgerufen, um die KundenInfo Rubrik anzuzeigen.
    '               
    '               ENGLISH:
    '               Requested parameters for a CustomerInfo query and stores it in the registry . After that, a browser tab is called to display the Customer Information section .
    ' #Copyright: © 2014 by Melville-Schellmann
    ' #Version: 1.2 (08.06.2015) Registry Parameter werden Gespeichert und geladen
    ' #Author: Robert Schellmann, rs@melville-schellmann.de, Wassim Amrou, wa@melville-schellmann.de
    ' #Version: 1.1 (08.08.2014) Verarbeitung von ACTFeldern und Registry-Werten als Parameter im KundenInfo
    ' #Version: 1.0 (24.04.2014) s.o.

    ' AddReference("Infragistics.Act.Win")

    Dim oParameters As ParameterManager
    
    ' Name der BrowserTab Konfiguration
    Dim sBrowserTabName As String = "KundenInfo (Aktueller Kontakt)"
    ' URL die Aufgerufen werden soll, wenn Leer-String dann wird ein Reload der aktuellen URL (Seite) aufgerufen.
    Dim sBrowserTabURL As String = "kundeninfo4://config/Kontaktbereich_AktuellerKontakt/rubrik/Abrechnung"
    ' Festlegung ob Parameter abgefragt werden sollen
    Dim bWithParameterInput As Boolean = True ' Bei True wird vor dem BrowserTab-Aufruf die Eingabe der Parameter angezeigt.
    
    m_sScriptName = "SetKIParameter"
    m_oACTApp = ACTApp
    m_oAutoData = AutoData
    
    m_oAutoData.refreshData
    System.Windows.Forms.Application.DoEvents
    If m_oAutoData.hasAnError Then
      MsgBox(m_oAutoData.ErrorMessage, MsgBoxStyle.Exclamation, m_sScriptName)
      GoTo Abbruch
    End If
    
    ' Parameter eingeben
    If bWithParameterInput Then
      oParameters = New ParameterManager("Eingabe der Suchparameter")
      oParameters.Load
      If oParameters.Edit = DialogResult.Cancel Then
        GoTo Abbruch
      End If 
      oParameters.Save
    End If   

    ShowBrowserTab(sBrowserTabName, sBrowserTabURL)
    
    Abbruch:
    Return String.Empty
  End Function
  
  ' Parameter Klasse
  ' Hat für jeden Paramter der in der KundenInfo-Abfrage verwendet wird eine Eigenschaft/Property
  ' Über das Attribut ActFieldName wird der Feldname für den Paramter angegeben bzw. über das
  ' Attribute RegistryValueName wird der Name des Registry-Eintrages für den Parameter angegeben.
  
  Private  Class ParameterManager
    
    ' Membervariablen für jeden Parameter eine Variable, Typ beachten

    Private m_lIntegerValue As Integer
    Private m_sSearchValue As String
    Private m_dStartDate As Date
    Private m_dEndDate As Date
    Private m_sHeadText As String
    Private m_sHeadDetails As String
    
    ' Private m_oACTApp As Act.UI.ActApplication
    Private m_sTitle As String    
    ' Für jeden Parameter wird eine Property definiert
    ' Über das Attribute ActFieldName kann das zugehörige ACT!-Feld definiert werden.
    &lt; _
      RegistryValueName("Suchbegriff01"), _
      System.ComponentModel.CategoryAttribute("Kriterien"), _
      System.ComponentModel.DisplayName("1. Suchbegriff"), _
      System.ComponentModel.DescriptionAttribute("Legt fest nach welchem Begriff die Daten durchsucht werden sollen.") _
      &gt; _    
    Public Property Suchbegriff01 As String
      Get 
        Return m_sSearchValue
      End Get
      Set (value As String)
        m_sSearchValue = value
      End Set
    End Property
    
    &lt; _
      RegistryValueName("Zahl01"), _
      System.ComponentModel.CategoryAttribute("Kriterien"), _
      System.ComponentModel.DisplayName("1. Zahleingabe"), _
      System.ComponentModel.DescriptionAttribute("Legt einen Zahlenwert fest.") _
      &gt; _    
    Public Property Zahl01 As Integer
      Get 
        Return m_lIntegerValue
      End Get
      Set (value As Integer)
        m_lIntegerValue = value
      End Set
    End Property
    
    &lt; _   
      RegistryValueName("WP_Start"), _
      System.ComponentModel.CategoryAttribute("Kriterien"), _
      System.ComponentModel.DisplayName("2. Startdatum"), _
      System.ComponentModel.DescriptionAttribute("Legt fest ab welchem Datum Daten verarbeitet werden sollen.") _
      &gt; _    
    Public Property Startdatum As Date
      Get 
        Return m_dStartDate
      End Get
      Set (value As Date)
        m_dStartDate = value
      End Set
    End Property
    
    &lt; _
      RegistryValueName("WP_Ende"), _
      System.ComponentModel.CategoryAttribute("Kriterien"), _
      System.ComponentModel.DisplayName("3. Enddatum"), _
      System.ComponentModel.DescriptionAttribute("Legt fest bis zu welchem Datum die Daten verarbeitet werden sollen.") _
      &gt; _    
    Public Property Enddatum As Date
      Get 
        Return m_dEndDate
      End Get
      Set (value As Date)
        m_dEndDate = value
      End Set
    End Property
    
    &lt; _
      RegistryValueName("HeadTitel"), _
      System.ComponentModel.CategoryAttribute("Layout"), _
      System.ComponentModel.DisplayName("1. Überschrift"), _
      System.ComponentModel.DescriptionAttribute("Legt die Überschrift fest.") _
      &gt; _    
    Public Property HeadText As String    
      Get 
        Return m_sHeadtext
      End Get
      Set (value As String)
        m_sHeadText = value
      End Set
    End Property
    
    'System.ComponentModel.Editor(GetType(Infragistics.Win.Design.MultiLineTextEditor), GetType(System.Drawing.Design.UITypeEditor)) _
    'C1.Win.C1Report.Design.StatementEditor
    &lt; _
      RegistryValueName("HeadDetails"), _
      System.ComponentModel.CategoryAttribute("Layout"), _
      System.ComponentModel.DisplayName("2. Beschreibung"), _
      System.ComponentModel.DescriptionAttribute("Legt die Beschreibung fest."), _
      System.ComponentModel.Editor(GetType(Infragistics.Win.Design.MultiLineTextEditor), GetType(System.Drawing.Design.UITypeEditor)) _
      &gt; _    
    Public Property HeadDetails As String
      Get 
        Return m_sHeadDetails   
      End Get
      Set (value As String)
        m_sHeadDetails = value
      End Set
    End Property
    
    ' Ende der Parameter definition
    
    #Region "Methods"   
    Public Sub New(sTitel As String)
      m_sTitle = sTitel
      
      ' Initialaisierungswerte für die Eigenschaftswerte
      
      m_lIntegerValue = 0
      m_sSearchValue = String.Empty
      m_dStartDate = now    
      m_dEndDate = m_dStartDate.AddDays(30)
      m_sHeadText = "Unbenannt"
      m_sHeadDetails = String.Empty
      
    End Sub   
    Public Function Edit() As System.Windows.Forms.DialogResult
      
      Dim frmEdit As System.Windows.Forms.Form
      Dim oPropertyGrid As System.Windows.Forms.PropertyGrid
      Dim cmdOK As System.Windows.Forms.Button
      Dim cmdCancel As System.Windows.Forms.Button
      
      frmEdit = New System.Windows.Forms.Form
      
      frmEdit.SuspendLayout
      
      With frmEdit
        .MinimumSize = New System.Drawing.Size(240, 180)
        .Width = 360
        .Height = 480
        .Text = m_sTitle
        .Icon = Icons.IconManager.GetIcon("cubes_all")
        .StartPosition = System.Windows.Forms.FormStartPosition.CenterParent
      End With
      
      cmdOK = New System.Windows.Forms.Button
      With cmdOK
        .DialogResult = DialogResult.OK
        .Name = "cmdOK"
        .Text = "OK"
        .Dock = DockStyle.Bottom
      End With
      cmdCancel = New System.Windows.Forms.Button
      With cmdCancel
        .DialogResult = DialogResult.Cancel
        .Name = "cmdCancel"
        .Text = "Abbruch"
        .Dock = DockStyle.Bottom
      End With
      oPropertyGrid = New System.Windows.Forms.PropertyGrid
      With oPropertyGrid 
        .Dock = DockStyle.Fill
        .SelectedObject = Me
        .ToolbarVisible = False
      End With  
      frmEdit.Controls.Add(oPropertyGrid)
      frmEdit.Controls.Add(cmdOK)
      frmEdit.Controls.Add(cmdCancel)
      frmEdit.AcceptButton = cmdOK
      frmEdit.CancelButton = cmdCancel

      AddHandler frmEdit.Load, AddressOf frmEdit_Load
      AddHandler frmEdit.KeyPress, AddressOf frmEdit_KeyPress
      AddHandler oPropertyGrid.PropertyValueChanged, AddressOf oPropertyGrid_PropertyValueChanged

      frmEdit.ResumeLayout
      
      Return frmEdit.ShowDialog(m_oACTApp)
    End Function
    Public Sub Save()
      Dim oPropertyInfo As System.Reflection.PropertyInfo
      Dim oValue As Object
      Dim sParameterName As String = Nothing
      
      For Each oPropertyInfo In Me.GetType.GetProperties()
        oValue = oPropertyInfo.GetValue(Me, Nothing)
        If oValue Is Nothing Then
          oValue = String.Empty
        End If
        ' ACTFeldName ist Paramatername
        If Not oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True) Is Nothing AndAlso _
          oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True).Length &gt; 0 Then
          sParameterName = CType(oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True)(0), actfieldname).name
          If TrySetFieldValueInCurrentACTEntity(sParameterName, oPropertyInfo.GetValue(Me, Nothing)) = False Then
            ' Der Parameter-Wert konnte nicht im ACT! Datensatz gespeichert werden.
          End If
        End If
        ' RegistryValueName ist Paramatername
        If Not oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True) Is Nothing AndAlso _
          oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True).Length &gt; 0 Then
          sParameterName = CType(oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True)(0), RegistryValueName).name
          If TrySetParameterValueInRegistry(sParameterName, oPropertyInfo.GetValue(Me, Nothing)) = False Then
            ' Der Parameter-Wert konnte nicht in der Registry gespeichert werden.
          End If  
        End If
      Next
    End Sub
    Public Sub Load()
      Dim oPropertyInfo As System.Reflection.PropertyInfo
      Dim sACTFieldName As String = Nothing
      Dim sParameterName As String = Nothing
      Dim attACTField As ACTFieldName
      Dim oValue As Object = Nothing
      
      For Each oPropertyInfo In Me.GetType.GetProperties()
        ' ACTFeldName ist Paramatername
        If Not oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True) Is Nothing AndAlso _
          oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True).Length &gt; 0 Then 
          attACTField = oPropertyInfo.GetCustomAttributes(GetType(ACTFieldName), True)(0)
          sACTFieldName = attACTField.Name
          If TryGetFieldValueInCurrentACTEntity(sACTFieldname, oValue) = True Then
            Try
              oPropertyInfo.SetValue(Me, oValue, Nothing)  
            Catch ex As Exception
              MsgBox(ex.message)
            End Try
          End If
        End If
        ' RegistryValueName ist Paramatername
        If Not oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True) Is Nothing AndAlso _
          oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True).Length &gt; 0 Then
          sParameterName = CType(oPropertyInfo.GetCustomAttributes(GetType(RegistryValueName), True)(0), RegistryValueName).name
          If TryGetParameterValueFromRegistry(sParameterName, oValue) = True Then
            Try
              If  oPropertyInfo.PropertyType Is GetType(Date) Then 
                oPropertyInfo.SetValue(Me, Date.Parse(oValue), Nothing) 
              End If
              If  oPropertyInfo.PropertyType Is GetType(String) Then 
                oPropertyInfo.SetValue(Me, oValue.ToString, Nothing) 
              End If
              If  oPropertyInfo.PropertyType Is GetType(Integer) Then 
                oPropertyInfo.SetValue(Me, Integer.Parse(oValue), Nothing) 
              End If             
                      
            Catch ex As Exception
              MsgBox(ex.message)
            End Try   
          End If        
        End If
      Next
    End Sub
    #End Region
    #Region "Events für Formular frmEdit"
    Private Shared Sub frmEdit_Load(ByVal sender As Object, ByVal e As System.EventArgs)
      system.Windows.Forms.SendKeys.Flush()
      system.Windows.Forms.SendKeys.SendWait("{TAB}")
      system.Windows.Forms.SendKeys.SendWait("{TAB}")
    End Sub
    Private Shared Sub frmEdit_KeyPress(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyPressEventArgs)

      Dim frmDataInput As system.Windows.Forms.Form
      Dim oInputGrid As system.Windows.Forms.PropertyGrid

      frmDataInput = CType(sender, system.Windows.Forms.Form)
      oInputGrid = CType(frmDataInput.Controls("prpInput"), system.Windows.Forms.PropertyGrid)
      If oInputGrid.Focused Then
        If oInputGrid.SelectedGridItem.GridItemType = GridItemType.Property Then
          Select Case e.KeyChar
            Case Microsoft.VisualBasic.ChrW(Keys.Return)
          End Select
        End If
      Else
        Select Case e.KeyChar
          Case Microsoft.VisualBasic.ChrW(Keys.Return)
            frmDataInput.DialogResult = DialogResult.OK
            frmDataInput.Close()
          Case Microsoft.VisualBasic.ChrW(Keys.Escape)
            frmDataInput.DialogResult = DialogResult.Cancel
            frmDataInput.Close()
          Case Else
        End Select
      End If
    End Sub
    Private Shared Sub oPropertyGrid_PropertyValueChanged(ByVal s As Object, ByVal e As system.Windows.Forms.PropertyValueChangedEventArgs)
      CType(s, system.Windows.Forms.PropertyGrid).Refresh()
      system.Windows.Forms.SendKeys.Flush()
      system.Windows.Forms.Application.DoEvents()
      Threading.Thread.Sleep(500)
      system.Windows.Forms.SendKeys.SendWait("{DOWN}")
      system.Windows.Forms.SendKeys.Flush()
      system.Windows.Forms.Application.DoEvents()
    End Sub
    #End Region
    #Region "Private Functions and Subs"
    Private Function TrySetParameterValueInRegistry(ByVal ParameterName As String, ByVal ParameterValue As Object) As Boolean
      TrySetParameterValueInRegistry = False
      Dim sRegKey As String = "Software\Melville-Schellmann\KundenInfo4\Values"
      Dim oRegKey As Microsoft.Win32.RegistryKey
      Try
        oRegKey = Microsoft.Win32.Registry.CurrentUser.OpenSubKey(sRegKey, True)  
      Catch ex As Exception
        Msgbox(String.Format("Es ist ein Fehler beim Zugriff auf den Registry-Key '{0}' aufgetreten.", sRegKey) &amp; vbcrlf &amp; ex.Message, MsgBoxStyle.Exclamation, m_sScriptName)
        GoTo Abbruch
      End Try
      If oRegKey Is Nothing Then
        Try
          oRegKey = Microsoft.Win32.Registry.CurrentUser.CreateSubKey(sRegKey)  
        Catch
          Msgbox(String.Format("Es ist ein Fehler beim Erstellen des Registry-Key '{0}' aufgetreten.", sRegKey), MsgBoxStyle.Exclamation, m_sScriptName)
          GoTo Abbruch
        End Try
      End If
      Try   
        oRegKey.SetValue(ParameterName, ParameterValue.ToString, Microsoft.Win32.RegistryValueKind.String)
        oRegKey.Close
      Catch ex As Exception
        Msgbox(String.Format("Es ist ein Fehler beim Setzen des Wertes '{0}' in dem Registry-Key '{1}' aufgetreten.", ParameterName, sRegKey) &amp; vbcrlf &amp; ex.Message, MsgBoxStyle.Exclamation, m_sScriptName)
        GoTo Abbruch
      End Try
      TrySetParameterValueInRegistry = True
      Abbruch:
    End Function
    Private Function TryGetParameterValueFromRegistry(ByVal ParameterName As String, ByRef ParameterValue As Object) As Boolean
      TryGetParameterValueFromRegistry = False
     
      Dim sRegKey As String = "Software\Melville-Schellmann\KundenInfo4\Values"
      Dim oRegKey As Microsoft.Win32.RegistryKey
      Try
        oRegKey = Microsoft.Win32.Registry.CurrentUser.OpenSubKey(sRegKey, True)  
      Catch ex As Exception
        ' Msgbox(String.Format("Es ist ein Fehler beim Zugriff auf den Registry-Key '{0}' aufgetreten.", sRegKey) &amp; vbcrlf &amp; ex.Message, MsgBoxStyle.Exclamation, m_sScriptName)
        GoTo Abbruch
      End Try
      
      Try
           
        ParameterValue = oRegKey.GetValue(ParameterName, ParameterValue)
      Catch ex As Exception
        ' Msgbox(String.Format("Beim Lesen des Wertes aus dem  Registry-Key '{0}' ist ein Fehler aufgetreten." &amp; vbcrlf &amp; ex.message, ParameterName), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End Try
       
 
     
      TryGetParameterValueFromRegistry = True
      Abbruch:
    End Function
    Private Function TryGetFieldValueInCurrentACTEntity(ACTFieldName As String, ByRef oValue As Object) As Boolean

      Dim oField As Act.Framework.MutableEntities.MutableEntityFieldDescriptor = Nothing
      Dim oEntity As act.Framework.MutableEntities.MutableEntity = Nothing
      'Dim m_oAutoData As Melville_Schellmann.ACTOptimum3.Control.AutoData3.AutoDataScript
      Dim lACTRegion As ActGlobal.ActRegion

      lACTRegion = ActGlobal.getCurrentActRegion(m_oActApp)
      oField = m_oAutoData.GetMutableEntityFieldDescriptor(lACTRegion, ACTFieldName)
      If oField Is Nothing Then
        Msgbox(String.Format("Es wurde nicht das Feld '{0}' im ACT!-{1}-Bereich gefunden.", ACTFieldName, lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End If            
      If TryGetCurrentEntity(oEntity) = False Then
        Msgbox(String.Format("Es wurde kein aktueller Datensatz für den ACT!-{0}-Bereich gefunden.", lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End If
      Try
        oValue = oField.GetValue(oEntity)  
      Catch ex As Exception
        Msgbox(String.Format("Beim Lesen des Wertes aus dem {1}-Feld '{0}' ist ein Fehler aufgetreten." &amp; vbcrlf &amp; ex.message, ACTFieldName, lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End Try
      Return True      
    End Function
    Private Function TrySetFieldValueInCurrentACTEntity(ACTFieldName As String, oValue As Object) As Boolean

      Dim oField As Act.Framework.MutableEntities.MutableEntityFieldDescriptor = Nothing
      Dim oEntity As act.Framework.MutableEntities.MutableEntity = Nothing
      'Dim m_oAutoData As Melville_Schellmann.ACTOptimum3.Control.AutoData3.AutoDataScript
      Dim lACTRegion As ActGlobal.ActRegion
    
      lACTRegion = ActGlobal.getCurrentActRegion(m_oActApp)
      oField = m_oAutoData.GetMutableEntityFieldDescriptor(lACTRegion, ACTFieldName)
      If oField Is Nothing Then
        Msgbox(String.Format("Es wurde nicht das Feld '{0}' im ACT!-{1}-Bereich gefunden.", ACTFieldName, lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End If            
      If TryGetCurrentEntity(oEntity) = False Then
        Msgbox(String.Format("Es wurde kein aktueller Datensatz für den ACT!-Bereich '{0}' gefunden.", lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End If
      Try
        oField.SetValue(m_oactapp.applicationstate.currentcontact, ovalue)  
        oEntity.Update
      Catch ex As Exception
        Msgbox(String.Format("Beim Setzen des Wertes '{0}' in das {2}-Feld '{1}' ist ein Fehler aufgetreten." &amp; vbcrlf &amp; ex.message, oValue, ACTFieldName, lACTRegion), MsgBoxStyle.Exclamation, m_sScriptName)
        Return False
      End Try
      Return True
    End Function
    Private Function TryGetCurrentEntity(ByRef oEntity As act.Framework.MutableEntities.MutableEntity) As Boolean
      Select Case  ActGlobal.getCurrentActRegion(m_oActApp)
        Case ActGlobal.ActRegion.Contact
          oEntity = m_oACTApp.ApplicationState.CurrentContact
        Case ActGlobal.ActRegion.Company
          oEntity = m_oACTApp.ApplicationState.CurrentCompany
        Case ActGlobal.ActRegion.[Group]
          oEntity = m_oACTApp.ApplicationState.CurrentGroup
        Case ActGlobal.ActRegion.Opportunity
          oEntity = m_oACTApp.ApplicationState.CurrentOpportunity
        Case Else
          oEntity = Nothing
          Return False
      End Select
      Return True
    End Function
    #End Region
  
  End Class

  &lt;System.AttributeUsage(System.AttributeTargets.Property)&gt; _
  Private Class ACTFieldName 
    Inherits System.Attribute
    Private m_sName As String
    Public Property Name As String
      Get
        Return m_sName
      End Get
      Set      (value As String)
        m_sName = value
      End Set
    End Property
    Public Sub New(ByVal FieldName As String)
      m_sName = FieldName
    End Sub
  End Class
  
  &lt;System.AttributeUsage(System.AttributeTargets.Property)&gt; _
  Private Class RegistryValueName 
    Inherits System.Attribute
    Private m_sName As String
    Public Property Name As String
      Get
        Return m_sName
      End Get
      Set      (value As String)
        m_sName = value
      End Set
    End Property
    Public Sub New(ByVal FieldName As String)
      m_sName = FieldName
    End Sub
  End Class  
  
  Public Shared m_oACTApp As Act.UI.ActApplication
  Public Shared m_oAutoData As Melville_Schellmann.ACTOptimum3.Control.AutoData3.AutoDataScript
  Public Shared m_sScriptName As String
  
  Private Shared Sub ShowBrowserTab(BrowserTabName As String, Optional URL As String = Nothing)
    
    Dim oTabControl As System.Windows.Forms.TabControl
    Dim oTabPage As System.Windows.Forms.TabPage
        
    oTabControl = CType(m_oACTApp.CurrentView, system.windows.Forms.Control).controls("PanelTabs").controls("Tabs")
    For Each oTabPage In oTabControl.TabPages
      If TypeOf(oTabPage) Is BrowserTab.BrowserTabPage Then
        If String.Compare(otabpage.Text, BrowserTabName, True) = 0 Then
          If Not oTabPage.Focused Then
            oTabControl.SelectedTab = oTabPage
            'm_oAutoData.ShowObjects(New Object() {CType(oTabPage, BrowserTab.BrowserTabPage)}) 
            If String.IsNullOrEmpty(url) Then
              CType(oTabPage, BrowserTab.BrowserTabPage).refreshCurrentPage
            Else
              CType(oTabPage, BrowserTab.BrowserTabPage).URL = URL
              CType(oTabPage, BrowserTab.BrowserTabPage).loadCurrentURL
            End If
          End If
        End If
      End If
    Next
  End Sub
  Private Shared Function Dummy() As String
    Return String.Empty</Source>
        <SourceComment>Begriff: {0}</SourceComment>
        <TargetFields></TargetFields>
        <MsgText>{0}</MsgText>
        <Picklist></Picklist>
        <Multiple>False</Multiple>
        <Expandable>True</Expandable>
        <OverwriteAlways>True</OverwriteAlways>
        <CopyToClipboard>False</CopyToClipboard>
        <ShowMsgBox>False</ShowMsgBox>
        <PositionMode>1</PositionMode>
        <FlatStyle>Standard</FlatStyle>
        <AutoDataText>SetKIParameter</AutoDataText>
        <TextAlign>MiddleCenter</TextAlign>
        <AutoDataFormSize>160; 270</AutoDataFormSize>
        <TooltipText></TooltipText>
        <RefreshLoadedViews>False</RefreshLoadedViews>
    </AutoDataControl>
</AutoDataItems>